求一个杀人奖励金钱的插件

ypf

金钱奖励插件 刀杀加钱 第一个杀人加钱 连杀加钱 还有 暴头,雷杀加钱, 与C4埋加钱与拆c4加钱

要原码谢谢了

jim_yang

2. #include <amxmodx>
3. #include <fakemeta>
5. #define PLUGIN    "Test"
6. #define AUTHOR    "Jim"
7. #define VERSION    "1.0"
9. #define MONEY_FUNCTION 3
11. #define get_player_team(%1) get_pdata_int(%1, 114)
13. #if MONEY_FUNCTION == 1
14.     #include <cstrike>
15.     #define add_player_money(%1,%2) cs_set_user_money(%1, cs_get_user_money(%1) + %2)
16. #else
17.     #if MONEY_FUNCTION == 2
18.         #include <unlimited_money>
19.         #define add_player_money(%1,%2) cs_set_user_money2(%1, cs_get_user_money2(%1) + %2)
20.     #else
21.         #define add_player_money(%1,%2) set_pdata_int(%1, 115, get_pdata_int(%1, 115) + %2)
22.     #endif
23. #endif
24.    
25. #define MONEY_KNIFE          1000
26. #define MONEY_GRENADE        300
27. #define MONEY_HEADSHOT       500
28. #define MONEY_FIRSTKILLER    1000
29. #define MONEY_KILLSTREAK     1000
30. #define MONEY_BOMBPLANTER    2000
31. #define MONEY_BOMBDEFUSER    2000
33. new bool:firstkiller
34. new lastkiller
36. stock get_loguser_index()
37. {
38.     new loguser[80], name[32]
39.     read_logargv(0, loguser, 79)
40.     parse_loguser(loguser, name, 31)
41.     return get_user_index(name)
42. }
44. public plugin_init()
45. {
46.     register_plugin(PLUGIN, VERSION, AUTHOR)
47.     register_event("DeathMsg", "event_death", "a")
48.     register_logevent("round_start", 2, "1=Round_Start")
49.     register_logevent("bomb_planted", 3, "2=Planted_The_Bomb")
50.     register_logevent("bomb_defused", 3, "2=Defused_The_Bomb")
51. }
53. public round_start()
54. {
55.     firstkiller = false
56.     lastkiller = 0
57. }
59. public bomb_planted()
60. {
61.     new id = get_loguser_index()
62.     if(is_user_connected(id))
63.         add_player_money(id, MONEY_BOMBPLANTER)
64. }
66. public bomb_defused()
67. {
68.     new id = get_loguser_index()
69.     if(is_user_connected(id))
70.         add_player_money(id, MONEY_BOMBDEFUSER)
71. }
73. public event_death()
74. {
75.     new k = read_data(1)
76.     new v = read_data(2)
77.    
78.     if(!k || k == v || get_player_team(k) == get_player_team(v))
79.         return
80.    
81.     if(k != lastkiller)
82.     {
83.         lastkiller = k
84.     }
85.     else
86.     {
87.         add_player_money(k, MONEY_KILLSTREAK)
88.     }
89.    
90.     if(!firstkiller)
91.     {
92.         add_player_money(k, MONEY_FIRSTKILLER)
93.         firstkiller = true
94.     }
95.    
96.     new w[3]
97.     read_data(3, w, 2)
98.    
99.     if(w[0] == 'k')
100.     {
101.         add_player_money(k, MONEY_KNIFE)
102.     }
103.     if(w[1] == 'r')
104.     {
105.         add_player_money(k, MONEY_GRENADE)
106.     }
107.     if(read_data(4))
108.     {
109.         add_player_money(k, MONEY_HEADSHOT)
110.     }
111. }

复制代码

jim_yang

说明一下MONEY_FUNCTION是设置你要使用哪个函数给玩家加钱
1是cstrike模块里的cs_g/set_user_money
2是金钱无限的native函数cs_g/set_user_money2
3是fakemeta的方法

编译时候自行选择，推荐3

那些MONEY_XXXX是加钱的项目，钱数你自己设置

另外连杀是什么我不是很清楚，这里定义连杀就是一个人接连杀人，中间不间隔其它人。