送大家一份圣诞礼物！

LittleKu

1. 
   
2. #include <amxmodx>
   
3. #include <amxmisc>
   
4. #include <fakemeta>
   
5. 
   
6. new const MODEL[ ] = "models/christmas/c4-christmastree.mdl";
   
7. 
   
8. public plugin_init( ) {
   
9.         register_clcmd( "say /tree", "CmdTreeMenu" );
   
10. }
    
11. 
    
12. public plugin_precache( ) {
    
13.         register_plugin( "Christmas tree spawner",  "0.1", "..." );
    
14.         precache_model( MODEL );
    
15.         engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString, "env_snow" ) );
    
16.        
    
17.         static szMapName[ 32 ], szConfig[ 128 ];
    
18.         get_mapname( szMapName, charsmax( szMapName ) );
    
19.         get_configsdir( szConfig, charsmax( szConfig ) );
    
20.         format( szConfig, charsmax( szConfig ), "%s/%s.txt", szConfig, szMapName );
    
21.        
    
22.         if ( file_exists( szConfig ) ) {
    
23.                 LoadTrees( szConfig )
    
24.         }
    
25. }
    
26. 
    
27. public CmdTreeMenu( id ) {
    
28.         if( !access( id, ADMIN_MAP ) )
    
29.                 return PLUGIN_HANDLED;
    
30.        
    
31.         ShowTreeMenu( id );
    
32.         return PLUGIN_HANDLED;
    
33. }
    
34. 
    
35. ShowTreeMenu( id ) {
    
36.         new menu = menu_create( "Tree Menu", "m_TreeMenu" );
    
37.        
    
38.         menu_additem( menu, "Create Tree", "1" );
    
39.         menu_additem( menu, "Delete All Tree", "2" );
    
40.         menu_additem( menu, "Save Menu", "3" );
    
41.        
    
42.         menu_display( id, menu );
    
43. }
    
44. 
    
45. public m_TreeMenu( id, menu, item ) {
    
46.         if( item == MENU_EXIT )
    
47.         {
    
48.                 menu_destroy( menu );
    
49.                 return;
    
50.         }
    
51.        
    
52.         static Float:flOrigin[ 3 ];
    
53.         static _access, info[ 2 ], callback;
    
54.         menu_item_getinfo( menu, item, _access, info, charsmax( info ), _,  _, callback );
    
55.         menu_destroy( menu );
    
56.        
    
57.         pev( id, pev_origin, flOrigin );
    
58.         switch( info[ 0 ] )
    
59.         {
    
60.                 case '1':
    
61.                 {
    
62.                         CreateTree( flOrigin );
    
63.                         ShowTreeMenu( id );
    
64.                 }
    
65.                 case '2':
    
66.                 {
    
67.                         RemoveAllTrees();
    
68.                         ShowTreeMenu( id );
    
69.                 }
    
70.                 case '3':
    
71.                 {
    
72.                         static szMapName[ 32 ], szConfig[ 128 ];
    
73.                         get_mapname( szMapName, charsmax( szMapName ) );
    
74.                         get_configsdir( szConfig, charsmax( szConfig ) );
    
75.                         format( szConfig, charsmax( szConfig ), "%s/%s.txt", szConfig, szMapName );
    
76.                        
    
77.                         SaveTrees( szConfig );
    
78.                 }
    
79.         }
    
80. }
    
81. 
    
82. CreateTree( const Float:flOrigin[ 3 ] ) {
    
83.         new iEntity = engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString, "info_target" ) );
    
84.        
    
85.         if( !iEntity )
    
86.                 return 0;
    
87.        
    
88.         set_pev( iEntity, pev_classname, "env_tree" );
    
89.         set_pev( iEntity, pev_solid, SOLID_BBOX );
    
90.         set_pev( iEntity, pev_movetype, MOVETYPE_NONE );
    
91.        
    
92.         engfunc( EngFunc_SetSize, iEntity, Float:{ -1.0, -1.0, -1.0 }, Float:{ 1.0,  1.0, 36.0 } );
    
93.         engfunc( EngFunc_SetOrigin, iEntity, flOrigin );
    
94.         engfunc( EngFunc_SetModel, iEntity, MODEL );
    
95.        
    
96.         engfunc( EngFunc_DropToFloor, iEntity );
    
97.        
    
98.         return iEntity;
    
99. }
    
100. 
     
101. SaveTrees( const szConfigFile[] ) {
     
102.         if( file_exists( szConfigFile ) )
     
103.                 delete_file( szConfigFile );
     
104.        
     
105.         new iFile = fopen( szConfigFile, "wt" );
     
106.        
     
107.         if( !iFile )
     
108.                 return;
     
109.        
     
110.         new Float:flOrigin[ 3 ], iEntity;
     
111.        
     
112.         while( ( iEntity = engfunc( EngFunc_FindEntityByString, iEntity, "classname", "env_tree" ) ) > 0  ) {
     
113.                 pev( iEntity, pev_origin, flOrigin );
     
114.                
     
115.                 fprintf( iFile, "%f %f %f^n", flOrigin[ 0 ], flOrigin[ 1 ],  flOrigin[ 2 ] );
     
116.         }
     
117.        
     
118.         fclose( iFile );
     
119. }
     
120. 
     
121. LoadTrees( const szConfigFile[] ) {
     
122.         new iFile = fopen( szConfigFile, "rt" );
     
123.        
     
124.         if( !iFile )
     
125.                 return 0;
     
126.        
     
127.         new Float:flOrigin[ 3 ], x[ 16 ], y[ 16 ], z[ 16 ], szData[ sizeof( x ) + sizeof( y ) + sizeof( z ) + 3 ];
     
128.        
     
129.         while( !feof( iFile ) ) {
     
130.                 fgets( iFile, szData, charsmax( szData ) );
     
131.                 trim( szData );
     
132.                
     
133.                 if( !szData[ 0 ] || szData[ 0 ] == ';' || ( szData[ 0 ] == '/' && szData[ 1 ] == '/' ) )
     
134.                         continue;
     
135.                
     
136.                 parse( szData, x, charsmax( x ), y, charsmax( y ), z, charsmax( z ) );
     
137.                
     
138.                 flOrigin[ 0 ] = str_to_float( x );
     
139.                 flOrigin[ 1 ] = str_to_float( y );
     
140.                 flOrigin[ 2 ] = str_to_float( z );
     
141.                
     
142.                 CreateTree( flOrigin );
     
143.         }
     
144.         return 1;
     
145. }
     
146. 
     
147. RemoveAllTrees( ) {
     
148.         new iEntity = -1;
     
149.        
     
150.         while( ( iEntity = engfunc( EngFunc_FindEntityByString, iEntity, "classname", "env_tree" ) ) > 0 )
     
151.                 engfunc( EngFunc_RemoveEntity, iEntity );
     
152. }  

复制代码

这是我刚刚在官方网的代码求救区看到的一个贴子，于是我就拿过来自己加工了一下！
由于没有测试环境，所以没有测试，有兴趣的朋友可以下来玩玩！:lol
祝大家圣诞快乐哈！:loveliness:

iam5362

顶 就是看不懂

76233386

貌似是官网的东东啊

114772348

这是什么插件源码?给个具体说明呀

LittleKu

顶 就是看不懂

这个是可以在读图上建立圣诞树！

貌似是官网的东东啊

请详细看一下我的说明！